Pentodi e spice

[mrttg]

Ciao,
oltre a quanto presente su sito di Duncan e Koren; e lo studio AES di Leach... conoscete altro in merito sul modellamento dei pentodi??

Grazie Tiziano

[Luc1gnol0]

conoscete altro in merito sul modellamento dei pentodi??
Originariamente inviato da mrttg - 06/02/2007 : 10:10:16

Penso di dirti cosa nota, ma sul sito di Stefano Perugini c'è una carrellata dei modelli più noti, in cui ci sono riferimenti anche a dei lavori di Rydel e Reynolds (metà anni '90).

http://digilander.libero.it/paeng/spice ... _tubes.htm

Un altro nome è Robert McLean, di cui trovi traccia tramite Google ed i principali forum/ng di DIY: non ho riferimenti web, ma credo non sia impossibile ritrovarne l'email: ha lavorato al miglioramento dei modelli da te citati ed alla loro integrazione in LTSpice/SwitcherCAD III.

Altri due "grossi" nomi della simulazione, Konar e Maillet, pare non se ne siano occupati, nei loro "ponderosi" lavori.

OH! (© by gluca) Il "noto" matematico/fisico teorico (tubofilo?) Teodoro Marinucci, a proposito della modellizzazione dei pentodi, pare abbia esclamato: "it drives me crazy!". Tiziano avvisato...

--- --- ---
Ciao, Luca

[mrttg]

OH! (© by gluca) Il "noto" matematico/fisico teorico (tubofilo?) Teodoro Marinucci, a proposito della modellizzazione dei pentodi, pare abbia esclamato: "it drives me crazy!". Tiziano avvisato...

--- --- ---
Ciao, Luca

Grazie delle indicazioni... mi era noto che questi modelli per quello che riguarda i pentodi hanno qualche pecca.

Mi sembra che ne accennasse anche Francesco Scarpa e JB nel suo programma TJPP (almeno nella versione di cui sono in possesso) per le valvole usa solo la configurazione a triodo.

Visto che l' argomento è di interesse generale condividete le vostre esperienze... con quali modelli spice dei pentodi vi siete trovati meglio

Tiziano

[Giaime]

Visto che l' argomento è di interesse generale condividete le vostre esperienze... con quali modelli spice dei pentodi vi siete trovati meglio

Tiziano


Originally posted by mrttg - 06/02/2007 : 20:28:12

Dunque, io ho una EL84, una EL34 e una 6L6GC che (nell'intorno delle tensioni e dei punti di lavoro più comuni con questi tubi) si comportano molto bene rispetto ai componenti reali.

Non so dove li ho pescati, per cui se servisse, eccoli:

Codice: Seleziona tutto

.SUBCKT EL34 1 2 3 4 ;  P G1 C G2
+ PARAMS: MU=11 EX=1.35 KG1=650 KG2=4200 KP=60 KVB=24
+         CCG=15P CPG1=1P CCP=8P RGI=1K 
RE1  7 0  1G      ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1   1 3  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2     4 3  VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP  1 3  1G      ; FOR CONVERGENCE
C1   2 3  {CCG}   ; CATHODE-GRID 1
C2   1 2  {CPG1}  ; GRID 1-PLATE
C3   1 3  {CCP}   ; CATHODE-PLATE
R1   2 5  {RGI}   ; FOR GRID CURRENT
D3   5 3  DX      ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT 6L6GC 1 2 3 4 ;  P G1 C G2
+ PARAMS: MU=8.7 EX=1.35 KG1=1460 KG2=4500 KP=48 KVB=12
+         CCG=14P CPG1=.85P CCP=12P RGI=1K 
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1   1 3  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2   4 3  VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP  1 3  1G      ; FOR CONVERGENCE
C1   2 3  {CCG}    ; CATHODE-GRID 1
C2   1 2  {CPG1}  ; GRID 1-PLATE
C3   1 3  {CCP}   ; CATHODE-PLATE
R1   2 5  {RGI}   ; FOR GRID CURRENT
D3   5 3  DX      ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT EL84D A S G K
*
* Calculate contribution to cathode current
*
Eat at 0 VALUE={0.636*ATAN(V(A,K)/15)}
Egs gs 0 VALUE={LIMIT{V(S,K)/19+V(G,K)+V(A,K)/400,0,1E6}}
Egs2 gs2 0 VALUE={PWRS(V(gs),1.5)}
Ecath cc 0 VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga A K VALUE={3.2E-3*V(cc)}
*
* Calculate screen current
*
Escrn sc 0 VALUE={V(gs2)*(1.1-V(at))}
Gs S K VALUE={2.0E-3*V(sc)}
*
* Grid current (approximation - does not model low va/vs)
*
Gg G K VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*50E-6}
*
* Capacitances
*
Cg1 G K 10.8p
Cak A K 6.5p
Cg1a G A 0.5p
.ENDS

Saluti termoionici
Giaime Ugliano

http://giaime.altervista.org