ECF82 Modello Spice

[mrttg]

Ciao a tutti,
qualcuno ha il modello spice di questo tubo funzionante grazie.

[FDG]

Ciao Tiziano, con LT funzionano bene, spero ti siano utili. Saluti F.

.SUBCKT ECF82P 1 2 3 4 ; A G2 G1 C (Pentode) ;PENTODE1 ; Universal Vademecum (1960) AKA 6U8
*PO(w)=3 Vmax(v)=500 Imax=20 Vgmax(-V)=-5 Vgstep(-V)=-0.5 Vg2(V)=110
+ PARAMS: MU=37.97 EX=1.350 KG1=849.8 KG2=4500 KP=90.97
+ KVB=20.1 VCT=0.00 RGI=2000
+ CCG=5.7p CPG1=0.6p CCP=4.1p
RE1 7 0 1MEG ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1 7 0 VALUE=
+{V(2,4)/KP*LOG(1+EXP((1/MU+V(3,4)/V(2,4))*KP))}; E1 BREAKS UP LONG EQUATION FOR G1.
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(EXP(EX*(LOG((V(2,4)/MU)+V(3,4)))))/KG2}
* G2 2 4 VALUE={PWR(V(2,4)/MU+V(3,4),EX)/KG2}
RCP 1 4 1G ; FOR CONVERGENCE A - C
C1 3 4 {CCG} ; CATHODE-GRID 1 C - G1
C2 1 3 {CPG1} ; GRID 1-PLATE G1 - A
C3 1 4 {CCP} ; CATHODE-PLATE A - C
R1 3 5 {RGI} ; FOR GRID CURRENT G1 - 5
D3 5 4 DX ; FOR GRID CURRENT 5 - C
.ENDS ECF82P

******************
.SUBCKT ECF82T 1 2 3 ; P G C (Triode) ; TRIODE SECTION ; WF data sheet AKA 6U8
*PO(w)=1.5 Vmax(v)= 280 Imax=16 Vgmax(-V)=-14 Vgstep(-V)=-1 Vg2(V)=
+ PARAMS: MU=49.87 EX=1.255 KG1=323.2 KP=106.38 KVB=300.0 VCT=0.00 RGI=2000
+ CCG=3.0p CGP=2.2p CCP=2.3p ;
E1 7 0 VALUE=
+{V(1,3)/KP*LN(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID;
C2 2 1 {CGP} ; GRID-PLATE;
C3 1 3 {CCP} ; CATHODE-PLATE;
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS ECF82T

[mrttg]

Grazie come simbolo usa il pentodo standard di LTSpice?

[FDG]

Ciao Tiziano
Il simbolo di LT è il tetrodo. Con il simbolo del pentodo non funziona. Saluti F.

[mrttg]

Sfasatore ECF81.jpg

Modello usato per simulare il circuito sopra funziona correttamente

[UnixMan]

[OT]
Uh? che roba strana è mai quella?
[/OT]

[mrttg]

[OT]
Uh? che roba strana è mai quella?
[/OT]

Stadio di ingresso e sfasatore del STA35 Renaissance Woodside, questo stadio sfasatore dovrebbe essere di Roger Bailey (lo stesso delle linee di trasmissione).